Did you know ... Search Documentation:
Predicate split_string/4
Availability:built-in
[det]split_string(+String, +SepChars, +PadChars, -SubStrings)
Break String into SubStrings. The SepChars argument provides the characters that act as separators and thus the length of SubStrings is one more than the number of separators found if SepChars and PadChars do not have common characters. If SepChars and PadChars are equal, sequences of adjacent separators act as a single separator. Leading and trailing characters for each substring that appear in PadChars are removed from the substring. The input arguments can be either atoms, strings or char/code lists. Compatible with ECLiPSe. Below are some examples:

A simple split wherever there is a‘.’: 

?- split_string("a.b.c.d", ".", "", L).
L = ["a", "b", "c", "d"].

Consider sequences of separators as a single one: 

?- split_string("/home//jan///nice/path", "/", "/", L).
L = ["home", "jan", "nice", "path"].

Split and remove white space: 

?- split_string("SWI-Prolog, 7.0", ",", " ", L).
L = ["SWI-Prolog", "7.0"].

Only remove leading and trailing white space (trim the string): 

?- split_string("  SWI-Prolog  ", "", "\s\t\n", L).
L = ["SWI-Prolog"].

In the typical use cases, SepChars either does not overlap PadChars or is equivalent to handle multiple adjacent separators as a single (often white space). The behaviour with partially overlapping sets of padding and separators should be considered undefined. See also read_string/5.

Examples

Strip text from leading and trailing white space

Strip text from leading and trailing white space

We can use split_string/4 to strip leading and trailing characters by using an empty set of split characters. Now we get a list with one element as reply. This can also be used to check that a string only holds a certain set of characters, e.g., the second examples validates that a string only holds white space. The last example illustrates that split_string/4 accept atoms as input.

?- split_string(" Hello world ", "", "\t\s", [Stripped]).
Stripped = "Hello world".

?- split_string(" \t", "", "\t\s", [""]).
true.

?- split_string(' \t', "", "\t\s", [""]).
true.
Read all lines to a list

Read all lines to a list

file_lines(File, Lines) :-
    setup_call_cleanup(open(File, read, In),
       stream_lines(In, Lines),
       close(In)).

stream_lines(In, Lines) :-
    read_string(In, _, Str),
    split_string(Str, "\n", "", Lines).

This loads all lines to memory as strings. If we use the Unix dictionary words:

?- file_lines("/usr/share/dict/words", Lines).
Words = ["A", "a", "aa", "aal", "aalii", "aam", "Aani", "aardvark", "aardwolf"|...].
Counting word frequency

Counting word frequency

word_frequency_count(Words, Counts) :-
    maplist(downcase_atom, Words, LwrWords),
    msort(LwrWords, Sorted),
    clumped(Sorted, Counts).
?- word_frequency_count([a,b,'A',c,d,'B',b,e], Counts).
Counts = [a-2, b-3, c-1, d-1, e-1].
See also
- tokenize_atom/2 or split_string/4 may be used to split a text into tokens
Tags are associated to your profile if you are logged in|Report abuse
Tags:
  • doc-needs-help
  • strip
  • trim
LogicalCaptain said (2020-09-03T12:32:21):0 upvotes 0 0 downvotes
Picture of user LogicalCaptain.

Trim/Strip

As said in the examples, this predicate can be used to trim strings, i.e. remove leading and trailing whitespace although there should really be a proper trim_string/2 and trim_atom/2 predicates. Naming discloses intent.

  • In Python, this operation is called strip
  • Java has both a strip and a trim for the String class, and they slightly differ.

However, there is no predicate to do that for atoms, lists-of-chars, or lists-of-codes. Does one have to transform these into a string and back? Sounds suboptimal.

A simple trim for atoms and list-of-char could be as follows (quite inefficient due to the way append/2 generates candidates to test, but rather compact):

% trim(Chars,TrimmedChars)

trim(Atom,TrimmedAtom) :-
   atom_chars(Atom,Chars),
   trim_chars(Chars,TrimmedChars),
   atom_chars(TrimmedAtom,TrimmedChars).

trim_chars(Chars,TrimmedChars) :-
   append([Prefix,TrimmedChars,Suffix],Chars),
   forall(member(X,Prefix),is_blank(X)),
   forall(member(X,Suffix),is_blank(X)),
   (
      TrimmedChars == [];
      (TrimmedChars = [First|_], \+is_blank(First), last(TrimmedChars,Last), \+is_blank(Last))
   ).

is_blank(X) :-
   memberchk(X,[' ','\n','\r','\t']). % should be extended to the whole unicode "blank" class

See also

atomic_list_concat/3, which is similar when it is run "in reverse".

Test code

:- begin_tests(split_string).

test("Simple split") :-
   split_string("a.b.c.d", ".", "", L),
   assertion(L == ["a", "b", "c", "d"]).

test("Split with sep-char at the extremities") :-
   split_string(".a.b.c.d.", ".", "", L),
   assertion(L == ["", "a", "b", "c", "d", ""]).

test("Split with sep-char sequence") :-
   split_string("a.b...c.d", ".", "", L),
   assertion(L == ["a","b","","","c","d"]).
   
test("Split with sep-char sequence, but collapse sequences") :-
   split_string("a.b...c.d", ".", ".", L),
   assertion(L == ["a","b","c","d"]).

test("Split with sep-char at the extremities, but collapse sequences") :-
   split_string(".a.b.c.d.", ".", ".", L),
   assertion(L == ["a","b","c","d"]).
   
test("Split with sep-char sequence, but collapse sequences, take 2") :-
   split_string("/home//jan///nice/path", "/", "/", L),
   assertion(L == ["home", "jan", "nice", "path"]).
      
test("Split and remove white space") :-
   split_string("SWI-Prolog, 7.0", ",", " ", L),
   assertion(L == ["SWI-Prolog", "7.0"]).
   
test("Remove leading and trailing white space, i.e.'trim' (no whitespace inside string)") :-
   split_string("  SWI-Prolog  ", "", "\s\t\n", L),
   assertion(L == ["SWI-Prolog"]).

test("Remove leading and trailing white space, i.e.'trim' (whitespace inside string)") :-
   split_string("  SWI Prolog  ", "", "\s\t\n", L),
   assertion(L == ["SWI Prolog"]).

test("Remove leading and trailing white space, i.e.'trim' (lots of whitespace inside string)") :-
   split_string("  SWI    Super   Prolog  ", "", "\s\t\n", L),
   assertion(L == ["SWI    Super   Prolog"]).
   
:- end_tests(split_string).
Plissken Armitage said (2017-06-06T19:15:27):0 upvotes 0 0 downvotes
Picture of user Plissken Armitage.
Predicate is available in SWI-Prolog 7.x.y. Doc-does-not-need-help.
Mahene said (2015-03-21T20:48:53):0 upvotes -1 -1 downvotes
Picture of user Mahene.
Predicate isn't present in SWI 6.6.6. The only thing that i could find and comes close is atomic_list_concat.