Did you know ... Search Documentation:
Predicate retract/1
Availability:built-in
[ISO,nondet]retract(+Term)
When Term is an atom or a term it is unified with the first unifying fact or clause in the database. The fact or clause is removed from the database. The retract/1 predicate respects the logical update view. This implies that retract/1 succeeds for all clauses that match Term when the predicate was called. The example below illustrates that the first call to retract/1 succeeds on bee on backtracking despite the fact that bee is already retracted.85Example by Jan Burse 
:- dynamic insect/1.
insect(ant).
insect(bee).

?- (   retract(insect(I)),
       writeln(I),
       retract(insect(bee)),
       fail
   ;   true
   ).
ant ;
bee.

If multiple threads start a retract on the same predicate at the same time their notion of the entry generation is adjusted such that they do not retract the same first clause. This implies that, if multiple threads use once(retract(Term)), no two threads will retract the same clause. Note that on backtracking over retract/1, multiple threads may retract the same clause as both threads respect the logical update view.

Tags are associated to your profile if you are logged in
Tags:
LogicalCaptain said (2020-05-22T12:12:16):0 upvotes 0 0 downvotes
Picture of user LogicalCaptain.

"logical update view" would be more correctly called "transactional update view"?

Having anything else would be just sub-par and impossible to reason about.

Note that retract/1 fails silently if the predicate is unknown:

?- retract(foo(a,b)).
false.

% Predicate is still unknown
?- predicate_property(foo(_,_),dynamic).
false.

?- assert(foo(a,b)).
true.

% Predicate is now known and dynamic
?- predicate_property(foo(_,_),dynamic).
true.

% Retract fact
?- retract(foo(a,b)).
true.

% Fact is now gone!
?- retract(foo(a,b)).
false.

A clause can be asserted multiple times (yes, they can!). In that case, retract/1 backtracks over the identical clauses:

?- assertz(foo(a,b)).
true.

?- assertz(foo(a,b)).
true.

?- bagof([X,Y],foo(X,Y),Bag).
Bag = [[a, b], [a, b]].

?- retract(foo(a,b)).
true ;
true.

?- retract(foo(a,b)).
false.

Consider retractall/1.