dnl Process this file with autoconf to produce a configure script.

AC_INIT(install-sh)
AC_PREREQ([2.50])
AC_CONFIG_HEADER(config.h)

AC_SUBST(TARGETS)
AC_SUBST(PLTARGETS)

m4_include([../ac_swi_c.m4])

case "$PLARCH" in
    *-win32|*-win64)
        AC_CHECK_LIB(ws2_32, main)
        AC_CHECK_LIB(gdi32, main)
        ;;
esac

AC_CHECK_LIB(crypto, main)
AC_CHECK_LIB(ssl, SSL_library_init)
AC_CHECK_TYPES(socklen_t, [], [],
[
#include <sys/types.h>
#include <sys/socket.h>
])

if test "$ac_cv_lib_ssl_SSL_library_init" = yes &&
   test	"$ac_cv_lib_crypto_main" = yes; then
  TARGETS="ssl4pl.$SO"
else
  echo "ERROR:   Cannot find ssl library"
  echo "WARNING: SSL interface will not be built"
  TARGETS=""
fi

AC_MSG_CHECKING(h_errno)
AC_TRY_COMPILE(
[
#include <sys/types.h>
#include <sys/socket.h>
#include <netdb.h>
#include <netinet/in.h>
],
[ int x = h_errno;
], AC_DEFINE(HAVE_H_ERRNO, 1,
	     [Define of h_errno is provided])
   AC_MSG_RESULT(yes),
   AC_MSG_RESULT(no))

AC_CHECK_FUNCS(timegm)

PLTARGETS=`echo $TARGETS | sed "s/4pl\.$SO/.pl/g"`

AC_OUTPUT(Makefile)